home *** CD-ROM | disk | FTP | other *** search
/ SPACE 1 / SPACE - Library 1 - Volume 1.iso / program / 441 / vdisrc12 / vdiinqr1.s < prev    next >
Text File  |  1990-11-23  |  3KB  |  90 lines
  1.  
  2. ;*========================================================================
  3. ;*
  4. ;* VDIFAST Public Domain VDI bindings.
  5. ;*
  6. ;* Maintenance:
  7. ;*  02/06/89    v1.1 - Changed misspelling of vq_extnd (was vq_extend).
  8. ;*                     Changed handle.l to handle.w in vq_extnd
  9. ;*========================================================================
  10.  
  11.           .iif      !(^^macdef VContrl),.include  "vdimacro.s"
  12.           
  13. ;*************************************************************************
  14. ;*
  15. ;* Inquiry functions.
  16. ;*  Some random ones.
  17. ;*************************************************************************
  18.           
  19. ;*------------------------------------------------------------------------
  20. ;* Extended inquire.
  21. ;*------------------------------------------------------------------------
  22.  
  23. _vq_extnd::
  24.           .cargs    #8,.handle.w,.owflag.w,.workout.l
  25.           link      a6,#0
  26.           
  27.           VContrl   #102,,,#1
  28.           
  29.           move.l    .workout(a6),a0
  30.           
  31.           pea       90(a0)              ;* -> ptsout
  32.           move.l    a0,-(sp)            ;* -> intout
  33.           subq.l    #4,sp               ;* -> ptsin
  34.           pea       .owflag(a6)         ;* -> intin
  35.           pea       16(sp)              ;* -> contrl
  36.           
  37.           jmp       vdicall
  38.           
  39. ;*------------------------------------------------------------------------
  40. ;* Inquire color representation.
  41. ;*------------------------------------------------------------------------
  42.           
  43. _vq_color::
  44.           .cargs    #8,.handle.w,.color.w,.setflag.w,.rgb.l
  45.           link      a6,#-8              ;* Allocate intout[4].
  46.  
  47.           VContrl   #26,,,#2
  48.  
  49.           subq.l    #4,sp               ;* -> ptsout
  50.           pea       -8(a6)              ;* -> intout
  51.           subq.l    #4,sp               ;* -> ptsin
  52.           pea       .color(a6)          ;* -> intin
  53.           pea       16(sp)              ;* -> contrl
  54.  
  55.           moveq.l   #$73,d0
  56.           move.l    sp,d1
  57.           trap      #2
  58.  
  59.           move.l    .rgb(a6),a0         ;* Return rgb array...
  60.           move.l    -6(a6),(a0)+        ;* rgb[0]=intout[1], rgb[1]=intout[2]
  61.           move.w    -2(a6),(a0)         ;* rgb[2]=intout[3]
  62.  
  63.           unlk      a6
  64.           rts
  65.         
  66. ;*------------------------------------------------------------------------
  67. ;* Inquire cell array - not supported.
  68. ;*------------------------------------------------------------------------
  69.  
  70. ;*------------------------------------------------------------------------
  71. ;* Inquire input mode.
  72. ;*------------------------------------------------------------------------
  73.  
  74. _vqin_mode::
  75.           .cargs    #8,.handle.w,.devtyp.w,.inmode.l
  76.           link      a6,#0
  77.  
  78.           VContrl   #115,,,#1
  79.           
  80.           subq.l    #4,sp               ;* -> ptsout
  81.           move.l    .inmode(a6),-(sp)   ;* -> intout
  82.           subq.l    #4,sp               ;* -> ptsin
  83.           pea       .devtyp(a6)         ;* -> intin
  84.           pea       16(sp)              ;* -> contrl
  85.  
  86.           jmp       vdicall 
  87.  
  88. ;         end of code
  89.  
  90.